alex/slang-shaders
1
0
Fork 0
mirror of https://github.com/italicsjenga/slang-shaders.git synced 2024-11-22 15:51:30 +11:00
Code Issues Packages Projects Releases Wiki Activity

add crt-hyllian-multipass

Browse source
This commit is contained in:
hunterk 2017-01-17 10:16:54 -06:00
parent c144d3d1aa
commit f8fac3677b
3 changed files with 272 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

20
crt/crt-hyllian-multipass.slangp Normal file
View file

@ -0,0 +1,20 @@
shaders = 2
shader0 = shaders/crt-hyllian-multipass/crt-hyllian-pass0.slang
filter_linear0 = false
srgb_framebuffer0 = true
scale_type_x0 = viewport
scale_type_y0 = source
scale_x0 = 1.0
scale_y0 = 1.0
shader1 = shaders/crt-hyllian-multipass/crt-hyllian-pass1.slang
filter_linear1 = false
srgb_framebuffer1 = false
scale_type_1 = source
// Uncomment these lines for a sharper variation
//parameters = "SHARPNESS;SCANLINES_STRENGTH;BEAM_MIN_WIDTH"
//SHARPNESS = "2.0"
//SCANLINES_STRENGTH = "0.50"
//BEAM_MIN_WIDTH = "0.44"

125
crt/shaders/crt-hyllian-multipass/crt-hyllian-pass0.slang Normal file
View file

@ -0,0 +1,125 @@
#version 450
/*
Hyllian's CRT Shader - pass0
Copyright (C) 2011-2016 Hyllian - sergiogdb@gmail.com
Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.
*/
layout(push_constant) uniform Push
{
vec4 SourceSize;
vec4 OriginalSize;
vec4 OutputSize;
uint FrameCount;
float SHARPNESS;
float CRT_ANTI_RINGING;
float InputGamma;
} params;
#pragma parameter SHARPNESS "CRT - Sharpness Hack" 1.0 1.0 5.0 1.0
#pragma parameter CRT_ANTI_RINGING "CRT - Anti-Ringing" 0.8 0.0 1.0 0.1
#pragma parameter InputGamma "CRT - Input gamma" 2.5 0.0 5.0 0.1
#define SHARPNESS params.SHARPNESS
#define CRT_ANTI_RINGING params.CRT_ANTI_RINGING
#define InputGamma params.InputGamma
layout(std140, set = 0, binding = 0) uniform UBO
{
mat4 MVP;
} global;
#define GAMMA_IN(color) pow(color, vec3(InputGamma, InputGamma, InputGamma))
// Horizontal cubic filter.
// Some known filters use these values:
// B = 0.0, C = 0.0 => Hermite cubic filter.
// B = 1.0, C = 0.0 => Cubic B-Spline filter.
// B = 0.0, C = 0.5 => Catmull-Rom Spline filter. This is the default used in this shader.
// B = C = 1.0/3.0 => Mitchell-Netravali cubic filter.
// B = 0.3782, C = 0.3109 => Robidoux filter.
// B = 0.2620, C = 0.3690 => Robidoux Sharp filter.
// B = 0.36, C = 0.28 => My best config for ringing elimination in pixel art (Hyllian).
// For more info, see: http://www.imagemagick.org/Usage/img_diagrams/cubic_survey.gif
// Change these params to configure the horizontal filter.
const float B = 0.0;
const float C = 0.5;
const mat4 invX = mat4( (-B - 6.0*C)/6.0, (12.0 - 9.0*B - 6.0*C)/6.0, -(12.0 - 9.0*B - 6.0*C)/6.0, (B + 6.0*C)/6.0,
(3.0*B + 12.0*C)/6.0, (-18.0 + 12.0*B + 6.0*C)/6.0, (18.0 - 15.0*B - 12.0*C)/6.0, -C,
(-3.0*B - 6.0*C)/6.0, 0.0, (3.0*B + 6.0*C)/6.0, 0.0,
B/6.0, (6.0 - 2.0*B)/6.0, B/6.0, 0.0);
#pragma stage vertex
layout(location = 0) in vec4 Position;
layout(location = 1) in vec2 TexCoord;
layout(location = 0) out vec2 vTexCoord;
void main()
{
gl_Position = global.MVP * Position;
vTexCoord = TexCoord;
}
#pragma stage fragment
layout(location = 0) in vec2 vTexCoord;
layout(location = 0) out vec4 FragColor;
layout(set = 0, binding = 2) uniform sampler2D Source;
void main()
{
vec2 texture_size = vec2(SHARPNESS*params.SourceSize.x, params.SourceSize.y);
vec3 color;
vec2 dx = vec2(1.0/texture_size.x, 0.0);
vec2 dy = vec2(0.0, 1.0/texture_size.y);
vec2 pix_coord = vTexCoord*texture_size+vec2(-0.5,0.0);
vec2 tc = (floor(pix_coord)+vec2(0.5,0.0))/texture_size;
vec2 fp = fract(pix_coord);
vec3 c10 = GAMMA_IN(texture(Source, tc - dx).xyz);
vec3 c11 = GAMMA_IN(texture(Source, tc ).xyz);
vec3 c12 = GAMMA_IN(texture(Source, tc + dx).xyz);
vec3 c13 = GAMMA_IN(texture(Source, tc + 2.0*dx).xyz);
// Get min/max samples
vec3 min_sample = min(c11,c12);
vec3 max_sample = max(c11,c12);
mat4x3 color_matrix = mat4x3(c10, c11, c12, c13);
vec4 lobes = vec4(fp.x*fp.x*fp.x, fp.x*fp.x, fp.x, 1.0);
vec4 invX_Px = invX * lobes;
color = color_matrix * invX_Px;
// Anti-ringing
vec3 aux = color;
color = clamp(color, min_sample, max_sample);
color = mix(aux, color, CRT_ANTI_RINGING);
FragColor = vec4(color, 1.0);
}

127
crt/shaders/crt-hyllian-multipass/crt-hyllian-pass1.slang Normal file
View file

@ -0,0 +1,127 @@
#version 450
/*
Hyllian's CRT Shader - pass1
Copyright (C) 2011-2016 Hyllian - sergiogdb@gmail.com
Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.
*/
layout(push_constant) uniform Push
{
vec4 SourceSize;
vec4 OriginalSize;
vec4 OutputSize;
uint FrameCount;
float OutputGamma;
float PHOSPHOR;
float COLOR_BOOST;
float RED_BOOST;
float GREEN_BOOST;
float BLUE_BOOST;
float SCANLINES_STRENGTH;
float BEAM_MIN_WIDTH;
float BEAM_MAX_WIDTH;
} params;
#pragma parameter OutputGamma "CRT - Output Gamma" 2.2 0.0 5.0 0.1
#pragma parameter PHOSPHOR "CRT - Phosphor ON/OFF" 1.0 0.0 1.0 1.0
#pragma parameter COLOR_BOOST "CRT - Color Boost" 1.5 1.0 2.0 0.05
#pragma parameter RED_BOOST "CRT - Red Boost" 1.0 1.0 2.0 0.01
#pragma parameter GREEN_BOOST "CRT - Green Boost" 1.0 1.0 2.0 0.01
#pragma parameter BLUE_BOOST "CRT - Blue Boost" 1.0 1.0 2.0 0.01
#pragma parameter SCANLINES_STRENGTH "CRT - Scanline Strength" 0.72 0.0 1.0 0.02
#pragma parameter BEAM_MIN_WIDTH "CRT - Min Beam Width" 0.86 0.0 1.0 0.02
#pragma parameter BEAM_MAX_WIDTH "CRT - Max Beam Width" 1.0 0.0 1.0 0.02
#define OutputGamma params.OutputGamma
#define PHOSPHOR params.PHOSPHOR
#define COLOR_BOOST params.COLOR_BOOST
#define RED_BOOST params.RED_BOOST
#define GREEN_BOOST params.GREEN_BOOST
#define BLUE_BOOST params.BLUE_BOOST
#define SCANLINES_STRENGTH params.SCANLINES_STRENGTH
#define BEAM_MIN_WIDTH params.BEAM_MIN_WIDTH
#define BEAM_MAX_WIDTH params.BEAM_MAX_WIDTH
layout(std140, set = 0, binding = 0) uniform UBO
{
mat4 MVP;
} global;
#define GAMMA_OUT(color) pow(color, vec3(1.0 / OutputGamma, 1.0 / OutputGamma, 1.0 / OutputGamma))
#pragma stage vertex
layout(location = 0) in vec4 Position;
layout(location = 1) in vec2 TexCoord;
layout(location = 0) out vec2 vTexCoord;
void main()
{
gl_Position = global.MVP * Position;
vTexCoord = TexCoord;
}
#pragma stage fragment
layout(location = 0) in vec2 vTexCoord;
layout(location = 0) out vec4 FragColor;
layout(set = 0, binding = 2) uniform sampler2D Source;
void main()
{
vec2 texture_size = params.SourceSize.xy;
vec3 color;
vec2 dx = vec2(1.0/texture_size.x, 0.0);
vec2 dy = vec2(0.0, 1.0/texture_size.y);
vec2 pix_coord = vTexCoord*texture_size+vec2(0.0,0.5);
vec2 tc = (floor(pix_coord)+vec2(0.0,0.5))/texture_size;
vec2 fp = fract(pix_coord);
vec3 color0 = texture(Source, tc - dy).xyz;
vec3 color1 = texture(Source, tc ).xyz;
float pos0 = fp.y;
float pos1 = 1 - fp.y;
vec3 lum0 = mix(vec3(BEAM_MIN_WIDTH), vec3(BEAM_MAX_WIDTH), color0);
vec3 lum1 = mix(vec3(BEAM_MIN_WIDTH), vec3(BEAM_MAX_WIDTH), color1);
vec3 d0 = clamp(pos0/(lum0+0.0000001), 0.0, 1.0);
vec3 d1 = clamp(pos1/(lum1+0.0000001), 0.0, 1.0);
d0 = exp(-10.0*SCANLINES_STRENGTH*d0*d0);
d1 = exp(-10.0*SCANLINES_STRENGTH*d1*d1);
color = clamp(color0*d0+color1*d1, 0.0, 1.0);
color *= COLOR_BOOST*vec3(RED_BOOST, GREEN_BOOST, BLUE_BOOST);
float mod_factor = vTexCoord.x * params.OutputSize.x;
vec3 dotMaskWeights = mix(
vec3(1.0, 0.7, 1.0),
vec3(0.7, 1.0, 0.7),
floor(mod(mod_factor, 2.0))
);
color.rgb *= mix(vec3(1.0, 1.0, 1.0), dotMaskWeights, PHOSPHOR);
color = GAMMA_OUT(color);
FragColor = vec4(color, 1.0);
}