mirror of
https://github.com/italicsjenga/slang-shaders.git
synced 2024-10-18 15:51:30 +11:00
330 lines
10 KiB
Plaintext
330 lines
10 KiB
Plaintext
#version 450
|
|
|
|
layout(push_constant) uniform Push
|
|
{
|
|
vec4 SourceSize;
|
|
vec4 OriginalSize;
|
|
vec4 OutputSize;
|
|
uint FrameCount;
|
|
float CURVATURE_toggle, CRTgamma, overscan_x, overscan_y, distance, radius, tiltangle_x, tiltangle_y, cornersize, cornersmooth;
|
|
} params;
|
|
|
|
#pragma parameter CURVATURE_toggle "Curvature Toggle" 1.0 0.0 1.0 1.0
|
|
#define CURVATURE bool(params.CURVATURE_toggle)
|
|
// gamma of simulated CRT
|
|
#pragma parameter CRTgamma "CRT Gamma" 2.4 1.0 4.0 0.05
|
|
#define CRTgamma params.CRTgamma
|
|
// overscan (e.g. 1.02 for 2% overscan)
|
|
#pragma parameter overscan_x "Overscan X" 1.0 0.0 2.0 0.01
|
|
#pragma parameter overscan_y "Overscan Y" 1.0 0.0 2.0 0.01
|
|
#define overscan vec2(params.overscan_x, params.overscan_y)
|
|
#pragma parameter distance "Viewing Distance" 2.0 0.1 5.0 0.1
|
|
#define distance params.distance
|
|
// radius of curvature
|
|
#pragma parameter radius "Curvature Radius" 2.0 0.1 5.0 0.1
|
|
#define radius params.radius
|
|
// tilt angle in radians
|
|
// (behavior might be a bit wrong if both components are nonzero)
|
|
#pragma parameter tiltangle_x "Tilt Angle X" 0.0 -1.0 1.0 0.05
|
|
#pragma parameter tiltangle_y "Tilt Angle Y" 0.0 -1.0 1.0 0.05
|
|
#define tiltangle vec2(params.tiltangle_x, params.tiltangle_y) + 0.001
|
|
// size of curved corners
|
|
#pragma parameter cornersize "Corner Size" 0.02 0.0001 0.1 0.01
|
|
#define cornersize params.cornersize
|
|
// border smoothness parameter
|
|
// decrease if borders are too aliased
|
|
#pragma parameter cornersmooth "Corner Smoothness" 800.0 0.8 2000.0 50.0
|
|
#define cornersmooth params.cornersmooth
|
|
|
|
layout(std140, set = 0, binding = 0) uniform UBO
|
|
{
|
|
mat4 MVP;
|
|
} global;
|
|
|
|
#pragma stage vertex
|
|
layout(location = 0) in vec4 Position;
|
|
layout(location = 1) in vec2 TexCoord;
|
|
layout(location = 0) out vec2 texCoord;
|
|
layout(location = 1) out vec3 stretch;
|
|
|
|
const vec2 aspect = vec2(1.0, 0.75);
|
|
float d = distance;
|
|
float R = radius;
|
|
vec2 sinangle = sin(tiltangle);
|
|
vec2 cosangle = cos(tiltangle);
|
|
|
|
vec2 one;
|
|
float mod_factor;
|
|
vec2 ilfac;
|
|
|
|
#define FIX(c) max(abs(c), 1e-5);
|
|
|
|
float intersect(vec2 xy)
|
|
{
|
|
float A = dot(xy,xy)+d*d;
|
|
float B = 2.0*(R*(dot(xy,sinangle)-d*cosangle.x*cosangle.y)-d*d);
|
|
float C = d*d + 2.0*R*d*cosangle.x*cosangle.y;
|
|
return (-B-sqrt(B*B-4.0*A*C))/(2.0*A);
|
|
}
|
|
|
|
vec2 bkwtrans(vec2 xy)
|
|
{
|
|
float c = intersect(xy);
|
|
vec2 point = vec2(c)*xy;
|
|
point -= vec2(-R)*sinangle;
|
|
point /= vec2(R);
|
|
vec2 tang = sinangle/cosangle;
|
|
vec2 poc = point/cosangle;
|
|
float A = dot(tang,tang)+1.0;
|
|
float B = -2.0*dot(poc,tang);
|
|
float C = dot(poc,poc)-1.0;
|
|
float a = (-B+sqrt(B*B-4.0*A*C))/(2.0*A);
|
|
vec2 uv = (point-a*sinangle)/cosangle;
|
|
float r = R*acos(a);
|
|
return uv*r/sin(r/R);
|
|
}
|
|
|
|
vec2 fwtrans(vec2 uv)
|
|
{
|
|
float r = FIX(sqrt(dot(uv,uv)));
|
|
uv *= sin(r/R)/r;
|
|
float x = 1.0-cos(r/R);
|
|
float D = d/R + x*cosangle.x*cosangle.y+dot(uv,sinangle);
|
|
return d*(uv*cosangle-x*sinangle)/D;
|
|
}
|
|
|
|
vec3 maxscale()
|
|
{
|
|
vec2 c = bkwtrans(-R * sinangle / (1.0 + R/d*cosangle.x*cosangle.y));
|
|
vec2 a = vec2(0.5,0.5)*aspect;
|
|
vec2 lo = vec2(fwtrans(vec2(-a.x,c.y)).x,
|
|
fwtrans(vec2(c.x,-a.y)).y)/aspect;
|
|
vec2 hi = vec2(fwtrans(vec2(+a.x,c.y)).x,
|
|
fwtrans(vec2(c.x,+a.y)).y)/aspect;
|
|
return vec3((hi+lo)*aspect*0.5,max(hi.x-lo.x,hi.y-lo.y));
|
|
}
|
|
|
|
void main()
|
|
{
|
|
gl_Position = global.MVP * Position;
|
|
texCoord = TexCoord;
|
|
stretch = maxscale();
|
|
}
|
|
|
|
#pragma stage fragment
|
|
layout(location = 0) in vec2 texCoord;
|
|
layout(location = 1) in vec3 stretch;
|
|
layout(location = 0) out vec4 FragColor;
|
|
layout(set = 0, binding = 2) uniform sampler2D Source;
|
|
|
|
// Comment the next line to disable interpolation in linear gamma (and gain speed).
|
|
//#define LINEAR_PROCESSING
|
|
|
|
// Enable 3x oversampling of the beam profile
|
|
#define OVERSAMPLE
|
|
|
|
// Use the older, purely gaussian beam profile
|
|
//#define USEGAUSSIAN
|
|
|
|
// gamma of display monitor (typically 2.2 is correct)
|
|
#define monitorgamma 2.2
|
|
|
|
// aspect ratio
|
|
const vec2 aspect = vec2(1.0, 0.75);
|
|
// lengths are measured in units of (approximately) the width of the monitor
|
|
// simulated distance from viewer to monitor
|
|
float d = distance;
|
|
float R = radius;
|
|
|
|
vec2 sinangle = sin(tiltangle);
|
|
vec2 cosangle = cos(tiltangle);
|
|
|
|
#define one (params.SourceSize.zw)
|
|
|
|
// Macros.
|
|
#define FIX(c) max(abs(c), 1e-5);
|
|
#define PI 3.141592653589
|
|
|
|
#ifdef LINEAR_PROCESSING
|
|
# define TEX2D(c) pow(texture(Source, (c)), vec4(CRTgamma))
|
|
#else
|
|
# define TEX2D(c) texture(Source, (c))
|
|
#endif
|
|
|
|
#define FIX(c) max(abs(c), 1e-5);
|
|
|
|
float intersect(vec2 xy)
|
|
{
|
|
float A = dot(xy,xy)+d*d;
|
|
float B = 2.0*(R*(dot(xy,sinangle)-d*cosangle.x*cosangle.y)-d*d);
|
|
float C = d*d + 2.0*R*d*cosangle.x*cosangle.y;
|
|
return (-B-sqrt(B*B-4.0*A*C))/(2.0*A);
|
|
}
|
|
|
|
vec2 bkwtrans(vec2 xy)
|
|
{
|
|
float c = intersect(xy);
|
|
vec2 point = vec2(c)*xy;
|
|
point -= vec2(-R)*sinangle;
|
|
point /= vec2(R);
|
|
vec2 tang = sinangle/cosangle;
|
|
vec2 poc = point/cosangle;
|
|
float A = dot(tang,tang)+1.0;
|
|
float B = -2.0*dot(poc,tang);
|
|
float C = dot(poc,poc)-1.0;
|
|
float a = (-B+sqrt(B*B-4.0*A*C))/(2.0*A);
|
|
vec2 uv = (point-a*sinangle)/cosangle;
|
|
float r = FIX(R*acos(a));
|
|
return uv*r/sin(r/R);
|
|
}
|
|
|
|
vec2 transform(vec2 coord)
|
|
{
|
|
coord = (coord-vec2(0.5))*aspect*stretch.z+stretch.xy;
|
|
return (bkwtrans(coord)/overscan/aspect+vec2(0.5));
|
|
}
|
|
|
|
float corner(vec2 coord)
|
|
{
|
|
coord = (coord - vec2(0.5)) * overscan + vec2(0.5);
|
|
coord = min(coord, vec2(1.0)-coord) * aspect;
|
|
vec2 cdist = vec2(cornersize);
|
|
coord = (cdist - min(coord,cdist));
|
|
float dist = sqrt(dot(coord,coord));
|
|
return clamp((cdist.x-dist)*cornersmooth,0.0, 1.0);
|
|
}
|
|
|
|
// Calculate the influence of a scanline on the current pixel.
|
|
//
|
|
// 'dist' is the distance in texture coordinates from the current
|
|
// pixel to the scanline in question.
|
|
// 'color' is the colour of the scanline at the horizontal location of
|
|
// the current pixel.
|
|
vec4 scanlineWeights(float dist, vec4 color)
|
|
{
|
|
// "wid" controls the width of the scanline beam, for each RGB channel
|
|
// The "weights" lines basically specify the formula that gives
|
|
// you the profile of the beam, i.e. the intensity as
|
|
// a function of distance from the vertical center of the
|
|
// scanline. In this case, it is gaussian if width=2, and
|
|
// becomes nongaussian for larger widths. Ideally this should
|
|
// be normalized so that the integral across the beam is
|
|
// independent of its width. That is, for a narrower beam
|
|
// "weights" should have a higher peak at the center of the
|
|
// scanline than for a wider beam.
|
|
#ifdef USEGAUSSIAN
|
|
vec4 wid = 0.3 + 0.1 * pow(color, vec4(3.0));
|
|
vec4 weights = vec4(dist / wid);
|
|
return 0.4 * exp(-weights * weights) / wid;
|
|
#else
|
|
vec4 wid = 2.0 + 2.0 * pow(color, vec4(4.0));
|
|
vec4 weights = vec4(dist / 0.3);
|
|
return 1.4 * exp(-pow(weights * inversesqrt(0.5 * wid), wid)) / (0.6 + 0.2 * wid);
|
|
#endif
|
|
}
|
|
|
|
void main()
|
|
{
|
|
// Here's a helpful diagram to keep in mind while trying to
|
|
// understand the code:
|
|
//
|
|
// | | | | |
|
|
// -------------------------------
|
|
// | | | | |
|
|
// | 01 | 11 | 21 | 31 | <-- current scanline
|
|
// | | @ | | |
|
|
// -------------------------------
|
|
// | | | | |
|
|
// | 02 | 12 | 22 | 32 | <-- next scanline
|
|
// | | | | |
|
|
// -------------------------------
|
|
// | | | | |
|
|
//
|
|
// Each character-cell represents a pixel on the output
|
|
// surface, "@" represents the current pixel (always somewhere
|
|
// in the bottom half of the current scan-line, or the top-half
|
|
// of the next scanline). The grid of lines represents the
|
|
// edges of the texels of the underlying texture.
|
|
|
|
// Texture coordinates of the texel containing the active pixel.
|
|
vec2 xy = CURVATURE ? transform(texCoord) : texCoord;
|
|
float cval = corner(xy);
|
|
|
|
// Of all the pixels that are mapped onto the texel we are
|
|
// currently rendering, which pixel are we currently rendering?
|
|
vec2 ratio_scale = xy * params.SourceSize.xy - vec2(0.5);
|
|
|
|
#ifdef OVERSAMPLE
|
|
float filter_ = fwidth(ratio_scale.y);
|
|
#endif
|
|
vec2 uv_ratio = fract(ratio_scale);
|
|
|
|
// Snap to the center of the underlying texel.
|
|
xy = (floor(ratio_scale) + vec2(0.5)) / params.SourceSize.xy;
|
|
|
|
// Calculate Lanczos scaling coefficients describing the effect
|
|
// of various neighbour texels in a scanline on the current
|
|
// pixel.
|
|
vec4 coeffs = PI * vec4(1.0 + uv_ratio.x, uv_ratio.x, 1.0 - uv_ratio.x, 2.0 - uv_ratio.x);
|
|
|
|
// Prevent division by zero.
|
|
coeffs = FIX(coeffs);
|
|
|
|
// Lanczos2 kernel.
|
|
coeffs = 2.0 * sin(coeffs) * sin(coeffs / 2.0) / (coeffs * coeffs);
|
|
|
|
// Normalize.
|
|
coeffs /= dot(coeffs, vec4(1.0));
|
|
|
|
// Calculate the effective colour of the current and next
|
|
// scanlines at the horizontal location of the current pixel,
|
|
// using the Lanczos coefficients above.
|
|
vec4 col = clamp(mat4(
|
|
TEX2D(xy + vec2(-one.x, 0.0)),
|
|
TEX2D(xy),
|
|
TEX2D(xy + vec2(one.x, 0.0)),
|
|
TEX2D(xy + vec2(2.0 * one.x, 0.0))) * coeffs,
|
|
0.0, 1.0);
|
|
vec4 col2 = clamp(mat4(
|
|
TEX2D(xy + vec2(-one.x, one.y)),
|
|
TEX2D(xy + vec2(0.0, one.y)),
|
|
TEX2D(xy + one),
|
|
TEX2D(xy + vec2(2.0 * one.x, one.y))) * coeffs,
|
|
0.0, 1.0);
|
|
|
|
#ifndef LINEAR_PROCESSING
|
|
col = pow(col , vec4(CRTgamma));
|
|
col2 = pow(col2, vec4(CRTgamma));
|
|
#endif
|
|
|
|
// Calculate the influence of the current and next scanlines on
|
|
// the current pixel.
|
|
vec4 weights = scanlineWeights(uv_ratio.y, col);
|
|
vec4 weights2 = scanlineWeights(1.0 - uv_ratio.y, col2);
|
|
#ifdef OVERSAMPLE
|
|
uv_ratio.y =uv_ratio.y+1.0/3.0*filter_;
|
|
weights = (weights+scanlineWeights(uv_ratio.y, col))/3.0;
|
|
weights2=(weights2+scanlineWeights(abs(1.0-uv_ratio.y), col2))/3.0;
|
|
uv_ratio.y =uv_ratio.y-2.0/3.0*filter_;
|
|
weights=weights+scanlineWeights(abs(uv_ratio.y), col)/3.0;
|
|
weights2=weights2+scanlineWeights(abs(1.0-uv_ratio.y), col2)/3.0;
|
|
#endif
|
|
vec3 mul_res = (col * weights + col2 * weights2).rgb * vec3(cval);
|
|
|
|
// dot-mask emulation:
|
|
// Output pixels are alternately tinted green and magenta.
|
|
vec3 dotMaskWeights = mix(
|
|
vec3(1.0, 0.7, 1.0),
|
|
vec3(0.7, 1.0, 0.7),
|
|
floor(mod(texCoord.x*params.OutputSize.x, 2.0))
|
|
);
|
|
|
|
mul_res *= dotMaskWeights;
|
|
|
|
// Convert the image gamma for display on our output device.
|
|
mul_res = pow(mul_res, vec3(1.0 / monitorgamma));
|
|
|
|
// Color the texel.
|
|
FragColor = vec4(mul_res, 1.0);
|
|
}
|