Merge pull request #2 from rz5/patch-2

Create crt-easymode.slang

crt/crt-easymode.slang

@@ -0,0 +1,182 @@
+#version 450
+
+layout(std140, set = 0, binding = 0) uniform UBO
+{
+   mat4 MVP;
+   vec4 OutputSize; /* .xy is Cg equivalent of output_size  */
+   vec4 OriginalSize;
+   vec4 SourceSize; /* .xy is Cg equivalent of both texture_size and video_size */
+} global;
+
+#pragma stage vertex
+layout(location = 0) in vec4 Position;
+layout(location = 1) in vec2 TexCoord;
+layout(location = 0) out vec2 vTexCoord;
+layout(location = 2) out vec2 coords;
+
+
+void main()
+{
+   gl_Position = global.MVP * Position;
+   vTexCoord = TexCoord;
+}
+
+/*
+    CRT Shader by EasyMode
+    License: GPL
+
+    A flat CRT shader ideally for 1080p or higher displays.
+
+    Recommended Settings:
+
+    Video
+    - Aspect Ratio: 4:3
+    - Integer Scale: Off
+
+    Shader
+    - Filter: Nearest
+    - Scale: Don't Care
+
+    Example RGB Mask Parameter Settings:
+
+    Aperture Grille (Default)
+    - Dot Width: 1
+    - Dot Height: 1
+    - Stagger: 0
+
+    Lottes' Shadow Mask
+    - Dot Width: 2
+    - Dot Height: 1
+    - Stagger: 3
+*/
+
+#pragma stage fragment
+layout(location = 0) in vec2 vTexCoord;
+layout(location = 1) in vec2 FragCoord;
+layout(location = 2) in vec2 coords;
+layout(location = 0) out vec4 FragColor;
+layout(set = 0, binding = 2) uniform sampler2D Source;
+
+#define SHARPNESS_H                 0.5 
+#define SHARPNESS_V                 1.0 
+#define MASK_STRENGTH               0.3 
+#define MASK_DOT_WIDTH              1.0 
+#define MASK_DOT_HEIGHT             1.0 
+#define MASK_STAGGER                0.0 
+#define MASK_SIZE                   1.0 
+#define SCANLINE_STRENGTH           1.0 
+#define SCANLINE_BEAM_WIDTH_MIN     1.5
+#define SCANLINE_BEAM_WIDTH_MAX     1.5 
+#define SCANLINE_BRIGHT_MIN         0.35
+#define SCANLINE_BRIGHT_MAX         0.65 
+#define SCANLINE_CUTOFF             400.0 
+#define GAMMA_INPUT                 2.0 
+#define GAMMA_OUTPUT                1.8 
+#define BRIGHT_BOOST                1.2 
+#define DILATION                    1.0 
+
+#define FIX(c) max(abs(c), 1e-5)
+#define PI 3.141592653589
+
+#define TEX2D(c) dilate(texture(Source, c))
+
+// Set to 0 to use linear filter and gain speed
+#define ENABLE_LANCZOS 1
+
+
+
+vec4 dilate(vec4 col)
+{
+    vec4 x = mix(vec4(1.0), col, DILATION);
+
+    return col * x;
+}
+
+float curve_distance(float x, float sharp)
+{
+
+/*
+    apply half-circle s-curve to distance for sharper (more pixelated) interpolation
+    single line formula for Graph Toy:
+    0.5 - sqrt(0.25 - (x - step(0.5, x)) * (x - step(0.5, x))) * sign(0.5 - x)
+*/
+
+    float x_step = step(0.5, x);
+    float curve = 0.5 - sqrt(0.25 - (x - x_step) * (x - x_step)) * sign(0.5 - x);
+
+    return mix(x, curve, sharp);
+}
+
+mat4x4 get_color_matrix(sampler2D tex, vec2 co, vec2 dx)
+{
+    return mat4x4(TEX2D(co - dx), TEX2D(co), TEX2D(co + dx), TEX2D(co + 2.0 * dx));
+}
+
+vec3 filter_lanczos(vec4 coeffs, mat4x4 color_matrix)
+{
+    vec4 col = coeffs * color_matrix;
+    vec4 sample_min = min(color_matrix[1], color_matrix[2]);
+    vec4 sample_max = max(color_matrix[1], color_matrix[2]);
+
+    col = clamp(col, sample_min, sample_max);
+
+    return col.rgb;
+}
+
+/* main_fragment */
+void main()
+{
+    vec2 dx     = vec2(1.0 / global.SourceSize.x, 0.0);
+    vec2 dy     = vec2(0.0, 1.0 / global.SourceSize.y);
+    vec2 pix_co = coords * global.SourceSize.xy - vec2(0.5, 0.5);
+    vec2 tex_co = (floor(pix_co) + vec2(0.5, 0.5)) / global.SourceSize.xy;
+    vec2 dist   = fract(pix_co);
+    float curve_x;
+    vec3 col, col2;
+
+#if ENABLE_LANCZOS
+    curve_x = curve_distance(dist.x, SHARPNESS_H * SHARPNESS_H);
+
+    vec4 coeffs = PI * vec4(1.0 + curve_x, curve_x, 1.0 - curve_x, 2.0 - curve_x);
+
+    coeffs = FIX(coeffs);
+    coeffs = 2.0 * sin(coeffs) * sin(coeffs / 2.0) / (coeffs * coeffs);
+    coeffs /= dot(coeffs, vec4(1.0));
+
+    col  = filter_lanczos(coeffs, get_color_matrix(Source, tex_co, dx));
+    col2 = filter_lanczos(coeffs, get_color_matrix(Source, tex_co + dy, dx));
+#else
+    curve_x = curve_distance(dist.x, SHARPNESS_H);
+
+    col  = mix(TEX2D(tex_co).rgb,      TEX2D(tex_co + dx).rgb,      curve_x);
+    col2 = mix(TEX2D(tex_co + dy).rgb, TEX2D(tex_co + dx + dy).rgb, curve_x);
+#endif
+
+    col = mix(col, col2, curve_distance(dist.y, SHARPNESS_V));
+    col = pow(col, vec3(GAMMA_INPUT / (DILATION + 1.0)));
+
+    float luma        = dot(vec3(0.2126, 0.7152, 0.0722), col);
+    float bright      = (max(col.r, max(col.g, col.b)) + luma) / 2.0;
+    float scan_bright = clamp(bright, SCANLINE_BRIGHT_MIN, SCANLINE_BRIGHT_MAX);
+    float scan_beam   = clamp(bright * SCANLINE_BEAM_WIDTH_MAX, SCANLINE_BEAM_WIDTH_MIN, SCANLINE_BEAM_WIDTH_MAX);
+    float scan_weight = 1.0 - pow(cos(coords.y * 2.0 * PI * global.SourceSize.y) * 0.5 + 0.5, scan_beam) * SCANLINE_STRENGTH;
+
+    float mask   = 1.0 - MASK_STRENGTH;    
+    vec2 mod_fac = floor(coords * global.OutputSize.xy * global.SourceSize.xy / (global.SourceSize.xy * vec2(MASK_SIZE, MASK_DOT_HEIGHT * MASK_SIZE)));
+    int dot_no   = int(mod((mod_fac.x + mod(mod_fac.y, 2.0) * MASK_STAGGER) / MASK_DOT_WIDTH, 3.0));
+    vec3 mask_weight;
+
+    if (dot_no == 0)      mask_weight = vec3(1.0, mask, mask);
+    else if (dot_no == 1) mask_weight = vec3(mask, 1.0, mask);
+    else                  mask_weight = vec3(mask, mask, 1.0);
+
+    if (global.SourceSize.y >= SCANLINE_CUTOFF) scan_weight = 1.0;
+
+    col2 = col.rgb;
+    col *= vec3(scan_weight);
+    col  = mix(col, col2, scan_bright);
+    col *= mask_weight;
+    col  = pow(col, vec3(1.0 / GAMMA_OUTPUT));
+
+    FragColor = vec4(col * BRIGHT_BOOST, 1.0);
+}